US Dollar Index Indikator

[adamp]

Der USD Index ist eine Kennzahl, die die Stärke des US-Dollars gegenüber anderen Währungspaaren anzeigt. Zur Berechnung werden diese US Dollar-Crosses verwendet:

• EURUSD
• USDJPY
• GBPUSD
• USDCAD
• USDSEK
• USDCHF
  

Nicht jede Währung ist gleich gewichtet und mit fast 60% fließt der Euro am stärksten in die Berechnung mit ein. Die genauen Angaben und weitere Informationen findet ihr bei Wikipedia: U.S._Dollar_Index

Es handelt sich dabei nicht um einen Indikator im klassischen Sinne. Er gibt keine Signale, aber zeigt z.B. ob ein Kursfall im EURUSD eher von einer Euro-Schwäche kommt oder durch eine USD-Stärke hervorgerufen wird.

Dies ist besonders dann interessant, wenn man Positionen in mehreren Währungen gleichzeitig eingegangen ist:

"Soll ich aus EURJPY aussteigen, weil EURUSD fällt? Soll ich in AUDUSD investieren, weil USDJPY fällt?"

Hier der Quellcode:

PHP-Code:

//+------------------------------------------------------------------+
//|                                                    USD Index.mq4 |
//|                                 Copyright © 2010, Metatrader5.de |
//|                                        http://www.metatrader5.de |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2010, Metatrader5.de"
#property link      "http://www.metatrader5.de"

#property indicator_separate_window
#property indicator_color1 Blue

//---- buffers
double ExtMapBuffer1[];


//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
{
   SetIndexStyle(0,DRAW_LINE);
   SetIndexBuffer(0,ExtMapBuffer1);

   return(0);
}


//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
{
   return(0);
}


//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
{   
   int limit;
   int counted_bars=IndicatorCounted();
   //---- check for possible errors
   if(counted_bars<0) return(-1);
   //---- the last counted bar will be recounted
   if(counted_bars>0) counted_bars--;
   limit=Bars-counted_bars;
   //---- main loop
   for(int i=limit; i>=0; i--)
   {
      double eurusd = iClose("EURUSD",0,i);
      double usdjpy = iClose("USDJPY",0,i);
      double gbpusd = iClose("GBPUSD",0,i);
      double usdcad = iClose("USDCAD",0,i);
      double usdsek = iClose("USDSEK",0,i);
      double usdchf = iClose("USDCHF",0,i);

      ExtMapBuffer1[i] = 50.14348112
        * MathPow(eurusd,-0.576)
        * MathPow(usdjpy,0.136)
        * MathPow(gbpusd,-0.119)
        * MathPow(usdcad,0.091)
        * MathPow(usdsek,0.042)
        * MathPow(usdchf,0.036);
   }
      
   return(0);
} 


Im Anhang findet ihr auch den kompilierten Indikator. Als Beispiel habe ich mal einen aktuellen Screenshot US Dollar Index Indikator im Tageschart von USDJPY, EURJPY und EURUSD beigefügt.

Man kann schön erkennen, wie der USD Index steigt und der USDJPY Kurs fällt. Das deutet daher auf einen starken Yen hin und weniger auf einen schwachen Dollar.

Diese Information bestätigt sich auch im Währungspaar EURJPY. Im Screenshot sieht man schön, dass EURJPY in dieser Zeit tatsächlich auch gefallen ist, was am starken Yen liegt.

EURUSD ist auch gefallen, was laut USD Index am starken Dollar liegt.